Problem Description

A Z-section cantilever shell model under torsional loading is considered in this example. Objective of the analysis is to compute the axial stress at X = 2.5 from fixed end. The geometry, dimensions and boundary conditions are shown in the figure below.
Solution Type: Linear Static
Unit: SI
Model Geometry: see the figure, thickness = 0.1m
Material Properties:
• Young’s Modulus: E = 210 GPa
• Poisson’s Ratio: nu = 0.3
Loading: Torque of 1.2 MN-m applied at X=10. The torque is applied by two uniformly distributed shear loads of 0.6 MN at each flange surface.
Boundary Conditions: All DOFs are fixed at X=0.
References:
[1]. The Standard NAFEMS Benchmarks, Rev. 3, October 1990


APDL CODE

 /PREP7
 ET,1,SHELL181 ! SHELL 181 ELEMENT
 KEYOPT,1,3,0 ! REDUCED INTEGRATION
 KEYOPT,1,8,2 ! STORE DATA FOR ALL LAYERS
 SECTYPE,1,SHELL
 SECDATA,0.1,1,0,5
 MP,EX,1,210E9
 MP,NUXY,1,0.3
 K,1,0,1,-1
 K,2,0,0,-1
 K,3,0,0,1
 K,4,0,-1,1
 K,5,10,-1,1
 K,6,10,0,1
 K,7,10,0,-1
 K,8,10,1,-1
 A,1,2,7,8
 A,2,3,6,7
 A,3,4,5,6
  
 ! Meshing
 ESIZE,1.25
 AMESH,1
 AMESH,3
 ALLSEL,ALL
 LESIZE,6,,,8
 LESIZE,2,,,8
 LESIZE,5,,,1
 LESIZE,7,,,1
 AMESH,2
  
 ! BCs and loading
 ALLSEL,ALL
 NUMMRG,NODE
 NSEL,S,LOC,X,0
 D,ALL,ALL,0 ! CANTILEVERED STRUCTURE
 NSEL,ALL
  
 NSEL,S,LOC,X,10
 NSEL,R,LOC,Y,0,1
 NSEL,R,LOC,Z,-1
 F,ALL,FY,600000 ! UNIFORMLY DISTRIBUTED EDGE SHEARS
 NSEL,S,LOC,X,10
 NSEL,R,LOC,Y,0,-1
 NSEL,R,LOC,Z,1
 F,ALL,FY,-600000 ! UNIFORMLY DISTRIBUTED EDGE SHEARS
 NSEL,ALL
 FINI
  
 ! Solution
 /SOLU
 ANTYPE,STATIC
 OUTRES,ALL,ALL
 NSUBS,10,10,10
 TIME,1
 SOLVE
 FINI
  
 ! Post-Processing
 /POST1
 SET,LAST
 N1=NODE(2.5,-1,1)
 SHELL,BOT ! BOTTOM SHELL LAYER
 PRNSOL,S
 *GET,SX1,NODE,N1,S,X ! AXIAL STRESS AT NODE 23 IN PA 

COMPARISON

Description NAFEMS [1] ANYSYS
Sigma_x at A (MPa) -108 -111.204