Problem Description

A plane stress problem with elliptic boundaries is considered in this example. The geometry, dimensions and boundary conditions are shown in the figure below.
Solution Type: Linear Static
Unit: SI
Model Geometry: see the figure
Material Properties:
• Young’s Modulus: E = 210E+3 MPa
• Poisson’s Ratio: nu = 0.3
Loading: Outward pressure at BC = 10 MPa
Boundary Conditions: Ux = 0 along AB; Uy = 0 along CD
References:
[1]. The Standard NAFEMS Benchmarks, Rev. 3, October 1990

APDL CODE

 FINI
 /CLEAR
 /PREP7
 ET,1,SHELL181 ! SHELL 181 ELEMENT
 KEYOPT,1,1,1 ! MEMBRANE STIFFNESS
 KEYOPT,1,3,2 ! FULL INTEGRATION
 SECTYPE,1,SHELL
 SECDATA,0.1,1
  
 ! Material properties
 MP,EX,1,210e9
 MP,NUXY,1,0.3
  
 ! Modeling
 K,1,0,1,0
 K,2,0.25,0.9921,0
 K,3,0.5,0.9682,0
 K,4,0.75,0.92702,
 K,5,1,0.8660254
 K,6,1.25,0.78062,
 K,7,1.5,0.661437
 K,8,1.75,0.4841229
 K,9,2.0,0
 K,10,2.25,0,
 K,11,2.50,0,
 K,12,2.75,0,
 K,13,3.0,0,
 K,14,3.25,0,
 K,15,3.0,1.05769
 K,16,2.75,1.46558
 K,17,2.50,1.7571
 K,18,2.25,1.9844
 K,19,2.00,2.1676
 K,20,1.75,2.3172
 K,21,1.50,2.4395
 K,22,1.25,2.5384
 K,23,1.00,2.6165
 K,24,0.75,2.6757
 K,25,0.50,2.7172
 K,26,0.25,2.7418
 K,27,0,2.75,0
 A,1,3,4,5,6,7,8,9,14,15,16,17,19,21,23,25,27
  
 ! Meshing
 LSEL,S,LINE,,17
 LSEL,A,LINE,,8
 LESIZE,ALL,,,5
 LSEL,S,LINE,,7,9,2
 LESIZE,ALL,,,5
 LSEL,S,LINE,,1,6,1
 LSEL,A,LINE,,10,16,1
 LESIZE,ALL,,,2
 AMESH,ALL
  
 ! Boundary conditions and Loading
 ALLSEL,ALL
 LSEL,S,LINE,,9,16,1
 NSLL,S,1
 SF,ALL,PRES,-10E6*0.1
 LSEL,ALL
 NSEL,S,LOC,X,0
 D,ALL,UX,0
 NSEL,ALL
 NSEL,S,LOC,Y,0
 D,ALL,UY,0
 NSEL,ALL
 D,ALL,UZ,0
 ALLSEL,ALL
 FINI
  
 ! Solution
 /SOLU
 ANTYPE,STATIC
 NSUBS,10,10,10
 OUTRES,ALL,ALL
 SOLVE
 FINI
  
 ! Post propcessing
 /POST1
 SET,LAST
 ND = NODE(2,0,0)
 *GET,SYD,NODE,ND,S,Y 

COMPARISON

Benchmarks Guide

Description NAFEMS [1] ANYSYS
Sigma_y at D 92.7 94.72